home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 3: CDPD 3 / Almathera Ten on Ten - Disc 3: CDPD3.iso / ab20 / unarced / graphics / anim / unvscomp.asm < prev   
Assembly Source File  |  1995-03-17  |  5KB  |  168 lines
  1. ;
  2. ; This file is presented exactly as found in the file riffsrc.arc on the BIX
  3. ; listings area for the AMiga except for the addition of the README file 
  4. ; from the same arc file at the front end.  This was added to justify the
  5. ; PD nature of this code despite the existence of the copyright notice in
  6. ; the original file.
  7. ;
  8. ; *** README file ***
  9. ;
  10. ; Hello
  11. ;     here's the source code in Aztec C and assembler for Playriff. 
  12. ; It must be compiled with 32-bit-ints.  Though the code is PD and may
  13. ; be put to whatever use you see fit, I'm not giving away free consulting
  14. ; time to support it.  Nevertheless here's how to get in touch with me
  15. ; if you have some questions.
  16. ; 
  17. ;    Jim Kent
  18. ;    Dancing Flame
  19. ;    739A 16th Ave.
  20. ;    San Francisco, CA 94118
  21. ;    or jim_kent on BIX.
  22. ;
  23. ; *** unvscomp.asm file ***
  24. ;
  25. ; unvscomp.asm  Copyright 1987 Dancing Flame all rights reserved.
  26. ;
  27. ; This file contains a single function which is set up to be called from
  28. ; C.  Ie the parameters are on the stack instead of registers.
  29. ;       decode_vkplane(in, out, linebytes)
  30. ; where in is a bit-plane's worth of vertical-byte-run-with-skips data
  31. ; and out is a bit-plane that STILL has the image from last frame on it.
  32. ; Linebytes is the number of bytes-per-line in the out bitplane, and it
  33. ; should certainly be noted that the external pointer variable ytable
  34. ; must be initialized to point to a multiplication table of
  35. ; 0*linebytes, 1*linebytes ... n*linebytes  before this routine is called.
  36. ; 
  37. ; The format of "in":
  38. ;   Each column of the bitplane is compressed separately.  A 320x200
  39. ;   bitplane would have 40 columns of 200 bytes each.  The linebytes
  40. ;   parameter is used to count through the columns, it is not in the
  41. ;   "in" data, which is simply a concatenation of columns.
  42. ;
  43. ;   Each columns is an op-count followed by a number of ops.
  44. ;   If the op-count is zero, that's ok, it just means there's no change
  45. ;   in this column from the last frame.
  46. ;   The ops are of three classes, and followed by a varying amount of
  47. ;   data depending on which class.
  48. ;       1. Skip ops - this is a byte with the hi bit clear that says how many
  49. ;          rows to move the "dest" pointer forward, ie to skip. It is non-
  50. ;          zero
  51. ;       2. Uniq ops - this is a byte with the hi bit set.  The hi bit is
  52. ;          masked down and the remainder is a count of the number of bytes
  53. ;          of data to copy literally.  It's of course followed by the
  54. ;          data to copy.
  55. ;       3. Same ops - this is a 0 byte followed by a count byte, followed
  56. ;          by a byte value to repeat count times.
  57. ;   Do bear in mind that the data is compressed vertically rather than
  58. ;   horizontally, so to get to the next byte in the destination (out)
  59. ;   we add linebytes instead of one!
  60. ;
  61.  
  62.     public _decode_vkplane
  63.  
  64. firstp    set    16
  65. in    set    4+firstp
  66. out    set    8+firstp
  67. linebytes    set    14+firstp
  68.  
  69. _decode_vkplane
  70.     movem.l    a2/a3/d4/d5,-(sp)  ; save registers for Aztec C
  71.     move.l    in(sp),a0
  72.     move.l    out(sp),a2
  73.     move.w    linebytes(sp),d2
  74.     move.l    _ytable,a3
  75.     move.w    d2,d4    ; make a copy of linebytes to use as a counter
  76.     bra    zdcp    ; And go to the "columns" loop
  77.  
  78. dcp
  79.     move.l    a2,a1     ; get copy of dest pointer
  80.     clr.w    d0    ; clear hi byte of op_count
  81.     move.b    (a0)+,d0  ; fetch number of ops in this column
  82.     bra    zdcvclp   ; and branch to the "op" loop.
  83.  
  84. dcvclp    clr.w    d1    ; clear hi byte of op
  85.     move.b    (a0)+,d1    ; fetch next op
  86.     bmi    dcvskuniq ; if hi-bit set branch to "uniq" decoder
  87.     beq dcvsame    ; if it's zero branch to "same" decoder
  88.  
  89. skip            ; otherwise it's just a skip
  90.     add.w    d1,d1    ; use amount to skip as index into word-table
  91.     adda.w    0(a3,d1),a1
  92.     dbra    d0,dcvclp ; go back to top of op loop
  93.     bra    z1dcp     ; go back to column loop
  94.  
  95. dcvsame            ;here we decode a "vertical same run"
  96.     move.b    (a0)+,d1    ;fetch the count
  97.     move.b    (a0)+,d3  ; fetch the value to repeat
  98.     move.w    d1,d5     ; and do what it takes to fall into a "tower"
  99.     asr.w    #3,d5     ; d5 holds # of times to loop through tower
  100.     and.w    #7,d1     ; d1 is the remainder
  101.     add.w    d1,d1
  102.     add.w    d1,d1
  103.     neg.w    d1
  104.     jmp    34+same_tower(pc,d1) ; why 34?  8*size of tower
  105.                                          ;instruction pair, but the extra 2's
  106.                                          ;pure voodoo.
  107. same_tower
  108.     move.b    d3,(a1)
  109.     adda.w    d2,a1
  110.     move.b    d3,(a1)
  111.     adda.w    d2,a1
  112.     move.b    d3,(a1)
  113.     adda.w    d2,a1
  114.     move.b    d3,(a1)
  115.     adda.w    d2,a1
  116.     move.b    d3,(a1)
  117.     adda.w    d2,a1
  118.     move.b    d3,(a1)
  119.     adda.w    d2,a1
  120.     move.b    d3,(a1)
  121.     adda.w    d2,a1
  122.     move.b    d3,(a1)
  123.     adda.w    d2,a1
  124.     dbra    d5,same_tower
  125.     dbra    d0,dcvclp
  126.     bra    z1dcp
  127.  
  128. dcvskuniq                     ; here we decode a "unique" run
  129.     and.b    #$7f,d1   ; setting up a tower as above....
  130.     move.w    d1,d5
  131.     asr.w    #3,d5
  132.     and.w    #7,d1
  133.     add.w    d1,d1
  134.     add.w    d1,d1
  135.     neg.w    d1
  136.     jmp    34+uniq_tower(pc,d1)
  137. uniq_tower
  138.     move.b    (a0)+,(a1)
  139.     adda.w    d2,a1
  140.     move.b    (a0)+,(a1)
  141.     adda.w    d2,a1
  142.     move.b    (a0)+,(a1)
  143.     adda.w    d2,a1
  144.     move.b    (a0)+,(a1)
  145.     adda.w    d2,a1
  146.     move.b    (a0)+,(a1)
  147.     adda.w    d2,a1
  148.     move.b    (a0)+,(a1)
  149.     adda.w    d2,a1
  150.     move.b    (a0)+,(a1)
  151.     adda.w    d2,a1
  152.     move.b    (a0)+,(a1)
  153.     adda.w    d2,a1
  154.     dbra    d5,uniq_tower  ; branch back up to "op" loop
  155. zdcvclp dbra    d0,dcvclp      ; branch back up to "column loop"
  156.  
  157.     ; now we've finished decoding a single column
  158. z1dcp    addq.l    #1,a2  ; so move the dest pointer to next column
  159. zdcp    dbra    d4,dcp ; and go do it again what say?
  160.     movem.l    (sp)+,a2/a3/d4/d5
  161.     rts
  162.  
  163.     dseg
  164.     public _ytable ; saves me 8 cycles/op ... a lookup table
  165.                    ; on the y addresses.
  166.  
  167.  
  168.